BEGIN { print "Datum;Betrag;Beschreibung;Belegnummer;Konto;Steuersatz;Betrieb;Bestandskonto" ; anzahl = 0 }

FNR > 1 {   # Header-Zeile überspringen

   gegenkonto = $4

   sub(/ *\"$/, "", gegenkonto)      # Leerzeichen und Anführungszeichen am Ende des Gegenkontos löschen

   sub(/^\"/, "", gegenkonto)       # Anführungszeichen am Anfang des Gegenkontos löschen

   sub(/^0*/, "", gegenkonto)      # Nullen am Anfang des Gegenkontos löschen

   

   gegenkontoinhaber = $6

   sub(/ *\"$/, "", gegenkontoinhaber)      # Leerzeichen und Anführungszeichen am Ende des Namens löschen

   sub(/^\"/, "", gegenkontoinhaber)       # Anführungszeichen am Anfang des Namens löschen

   

   betrag = $7

   betrag_mit_dezimalpunkt = betrag

   sub(/ *\"$/, "", betrag)   # Anführungszeichen am Ende des Betrags löschen

   sub(/^\"/, "", betrag)       # Anführungszeichen am Anfang des Betrags löschen

   sub(/,/, ".", betrag);      # Komma durch Punkt ersetzen   

   

   datum = $9

   belegnummer = ""

   

   # Verwendungszwecke miteinander verschmelzen, dabei störende Anführungszeichen abschneiden

   verwendungszweck = $10  

   verwendungszweck2 = $11

   verwendungszweck3 = $17

   verwendungszweck = substr(verwendungszweck, 2)

   sub(/\"$/, "", verwendungszweck)    

   verwendungszweck2 = substr(verwendungszweck2, 2)

   sub(/\"$/, "", verwendungszweck2)    

   verwendungszweck3 = substr(verwendungszweck2, 2)

   sub(/\"$/, "", verwendungszweck3) 

   verwendungszweck = verwendungszweck verwendungszweck2 verwendungszweck3



   konto = "--> Konto manuell zuweisen und Steuersatz checken!"

   steuersatz = 0

   

   IGNORECASE = 1

   switch (gegenkontoinhaber)

   {

   # Einnahmen

   case "RETELL LIMITED":   # ein Kunde von mir

      if (betrag > 0)

         konto = "Lizenzeinnahmen Retell UST-ID GB442507958";

         break

   case "AMAZON.DE MUENCHEN":   # Hier bekomme ich Geld, wenn jemand über den Buchtipps-Link auf easyct.de Steuerfachliteratur kauft

      if (betrag > 0)

         konto = "Amazon Werbekostenerstattungen UST-ID LU20260743"

         break

      

   # Ausgaben

   case "Michael Zoellner":   # antlg. Miete für Soundstudionutzung

      if (betrag < 0)

         konto = "Anmietung von Gewerbefläche"

      break

   case "Thomas Mielke":   # Privatentnahmen auf mein Privatkonto

   case "MIELKE, THOMAS":

      if (gegenkonto == 1942522)

      {

         if (betrag < 0)

            konto = "/Privatentnahmen"

         else

            konto = "/Privateinlagen"

      }

      else if (gegenkonto == 5531742023)   # ist ein weiteres Geschäftskonto von mir

         konto = "/Transfers zwischen Geschäftskonten"

      break

   case "PAYPAL":      # Abbuchungen von PayPal ans Bankkonto

      konto = "/Transfers zwischen Geschäftskonten"

      belegnummer = substr(verwendungszweck, 1, 16)   # PayPal Transaktionsnummer als Belegnummer verwenden

      verwendungszweck = substr(verwendungszweck, 18) # restlichen Verwendungszweck beibehalten

      break

   case "GVL":       # gelegentliche private Zahlung vom Geschäftskonto aus

      if (betrag < 0)

         konto = "/Privatentnahmen"      

      break;

   case "AV.COM":      # ein Zulieferer, Auftragsbestätigungsnummer im Verwendungszweck als Belegnummer nehmen

      if (betrag < 0)

      {

         konto = "Medienkosten"

         steuersatz = 19

      }      

      break      

   case /DEUTSCHE POST/:   # Krempel aus dem Post-Shop mit MWSt. bezhahle ich immer bar, 

      {      # Briefmarken und Pakete immer mit Karte -- so komme ich nicht durcheinander

         konto = "Porto"

         steuersatz = 0

      }

      break   

   case "Steuerkasse Hamburg":

      if (betrag < 0)

      {

         if (verwendungszweck ~ /VORAUSZAHLUNG/)

            konto = "/Privatentnahmen"   # Einkommensteuerzahlungen mache ich von meinem Geschäftskonto

         else if (verwendungszweck ~ /UST 20[0-9][0-9]/)

            konto = "Umsatzsteuerzahlungen an das Finanzamt"   # USt-Zahlung

            

      }

      else

         konto = "Umsatzsteuererstattungen des Finanzamts"      # USt-Erstattung

      break   

   default:   

      # Einnahmen und kein Bekannter Gegenkontoinhaber? Dann muss es wohl ein EC&T-Spender sein :)

      if (betrag > 0)

      {

         # Spendenbeträge sind meist duch 5 teilbar, den Rest auf Schlüsselworte im Verwendungszweck checken

         if (!(betrag % 5) || verwendungszweck ~ /EasyCash/ || verwendungszweck ~ /Spende/ || verwendungszweck ~ /Beitrag/ || verwendungszweck ~ /-AT-/)   

         {

            konto = "Software-Spenden (Charityware)"

            steuersatz = 7   # ermäßigter Steuersatz für Umsätze, die mit dem Urheberschutzgesetzt in Zusammenhang stehen

         }

      }

      

      # sonstige Ausgaben sind meist mit 19% MWSt.; checke ich, wenn ich das Konto manuell zuweise

      if (betrag < 0)

         steuersatz = 19;

   }



   # Belegnummer aus Verwendungszweck herausfischen, so gut es geht

   position = match(verwendungszweck, /R[0-9][0-9][0-9][0-9][0-9][^0-9]/)

   if (position > 0)

   {

          belegnummer = substr(verwendungszweck, position, 6);

   }

   else 

   {

      position = match(verwendungszweck, /RECHNUNG [0-9][0-9][0-9][0-9][0-9][^0-9]/)

      if (position > 0)

      {

             belegnummer = "R" substr(verwendungszweck, position+9, 5);

      }

      else 

      {

         position = match(verwendungszweck, /RE.NR. [0-9][0-9][0-9][0-9][0-9][^0-9]/)

         if (position > 0)

         {

                belegnummer = "R" substr(verwendungszweck, position+6, 5);

         }

      }



   }









   # wegen Fließkommaungenauigkeiten nehmen wir lieber den ursprünglichen Betrag als Zeichenkette, ansonsten müssten wir noch in etwa sowas machen:

   #betrag = sprintf("%.2f", betrag + 0.005);          # auf 2 Stellen nach dem Komma kürzen, dabei kaufmännisch runden

   #sub(/\./, ",", betrag);                            # jetzt den Dezimalpunkt wieder durchs Komma ersetzen



   # Beschreibungstext aufbereiten   

   beschreibung = "\"" gegenkontoinhaber

   beschreibung = beschreibung " / " verwendungszweck "\""         # verwendungszweck beginnt auch mit einem Anführungszeichen

   

   betrieb = "Softwareentwicklung"            # auf dem ING-Diba Konto laufen nur Zahlungen für meinen Haupt-Betrieb

   bestandskonto = "ING Diba"



   # Ausgabe der umgewandelten CSV-Zeile   

   print datum ";\"" betrag_mit_dezimalpunkt "\";" beschreibung ";" belegnummer ";" konto ";" steuersatz ";" betrieb ";" bestandskonto

   

   # hochzählen für die Statistik

   anzahl = anzahl + 1

}

END { print anzahl " Zeilen verarbeitet" > "/dev/stderr" }   # so gibt man Status- oder Fehlermeldungen im Kommandozeilenfenster aus